home *** CD-ROM | disk | FTP | other *** search
/ CU Amiga Super CD-ROM 25 / CU Amiga Magazine's Super CD-ROM 25 (1998)(EMAP Images)(GB)(Track 1 of 2)[!][issue 1998-08].iso / CUCD / WWW / http / www.wirenet.co.uk / files / thor25_arexx.lha / CygnusEd / CancelEvent.ced next >
Text File  |  1996-07-01  |  2KB  |  68 lines
  1. /* $VER: CancelEvent.ced 1.1 (24.6.96)
  2.    by Remco van Hooff
  3.    based on the ged version by Troels Walsted Hansen
  4.    
  5.    Quit CED without saving and delete the event in THOR.
  6.  
  7.    Install it under a function key in CED (don't put 'rx' infront of it!)
  8.  
  9.    HISTORY
  10.    1.1 - Fixed a problem with the Thor ARexx port.
  11.        - Will now work correctly with multiple CEDs open.
  12. */
  13.  
  14. options results
  15.  
  16. /* quit without saving */
  17. 'status 21'
  18. filename = result
  19. 'Quit & die 1'
  20.  
  21. p=' '||ADDRESS()||' '||SHOW('P',,)
  22. IF POS(' THOR.',p)>0 THEN thorport=WORD(SUBSTR(p,POS(' THOR.',p)+1),1)
  23. ELSE DO
  24.   SAY 'THOR port not found!'
  25.   EXIT 10
  26. END
  27.  
  28. IF ~SHOW('p', 'BBSREAD') THEN DO
  29.   ADDRESS COMMAND
  30.   "run >nil: `GetEnv THOR/THORPath`bin/LoadBBSRead"
  31.   "WaitForPort BBSREAD"
  32. END
  33.  
  34. ADDRESS(thorport)
  35. CURRENTBBS stem CURRENT
  36. IF(RC ~= 0 | CURRENT.BBSNAME ~= "") THEN bbs = CURRENT.BBSNAME
  37. ELSE EXIT
  38.  
  39. ADDRESS(bbsread)
  40. GETBBSDATA '"'bbs'"' stem BBSDATA
  41. IF(RC ~= 0) THEN DO
  42.   ADDRESS(thorport)
  43.   REQUESTNOTIFY TEXT '"'BBSREAD.LASTERROR'"' BT '"_Ok"'
  44.   EXIT 5
  45. END
  46.  
  47. DO i=BBSDATA.FIRSTEVENT TO BBSDATA.LASTEVENT
  48.   DROP MSGTAGS.
  49.   READBREVENT BBSNAME '"'bbs'"' EVENTNR i TAGSSTEM MSGTAGS
  50.   IF(RC ~= 0) THEN DO
  51.     ADDRESS(thorport)
  52.     REQUESTNOTIFY TEXT '"'BBSREAD.LASTERROR'"' BT '"_Ok"'
  53.     EXIT 5
  54.   END
  55.  
  56.   IF(filename = MSGTAGS.MSGFILE) THEN DO
  57.     UPDATEBREVENT BBSNAME '"'bbs'"' EVENTNR i SETDELETED
  58.     IF(RC ~= 0) THEN DO
  59.       ADDRESS(thorport)
  60.       REQUESTNOTIFY TEXT '"'BBSREAD.LASTERROR'"' BT '"_Ok"'
  61.       EXIT 5
  62.     END
  63.     EXIT
  64.   END
  65. END
  66.  
  67. EXIT
  68.